add library, library-manifest, and library-publish

src/main/kotlin/ltd.lulz.plugin.common-plugin.library-manifest.gradle.kts

@@ -0,0 +1,18 @@
+plugins {
+    id("ltd.lulz.plugin.core-plugin")
+}
+
+tasks.withType<Jar>().configureEach {
+    manifest.attributes.apply {
+        put("Implementation-Title", project.name.split("-").joinToString(" "))
+        put("Implementation-Version", project.version)
+        put("Implementation-Vendor", info.vendorName)
+        put("Built-By", System.getProperty("user.name"))
+        put("Built-Git", "${git.currentBranch()} #${git.currentShortHash()}")
+        put("Built-Gradle", project.gradle.gradleVersion)
+        put("Built-JDK", System.getProperty("java.version"))
+        put("Built-OS", "${System.getProperty("os.name")} v${System.getProperty("os.version")}")
+        put("Built-Time", info.utcTimestamp)
+    }
+}
+

src/main/kotlin/ltd.lulz.plugin.common-plugin.library-publish.gradle.kts

@@ -0,0 +1,19 @@
+plugins {
+    id("ltd.lulz.plugin.core-plugin")
+
+    `maven-publish`
+}
+
+publishing {
+    repositories {
+        maven {
+            url = uri("https://gitea.lulz.ltd/api/packages/aura-ascend/maven")
+            name = "GiteaPackages"
+            credentials {
+                username = config.find("repository.gitea.user", "REPOSITORY_USER")
+                password = config.find("repository.gitea.token", "REPOSITORY_TOKEN")
+            }
+        }
+    }
+    publications.register("mavenJava", MavenPublication::class) { from(components["java"]) }
+}

src/main/kotlin/ltd.lulz.plugin.common-plugin.library.gradle.kts

@@ -0,0 +1,21 @@
+import org.springframework.boot.gradle.tasks.bundling.BootJar
+
+plugins {
+    id("ltd.lulz.plugin.common-plugin.common")
+    id("ltd.lulz.plugin.common-plugin.library-manifest")
+    id("ltd.lulz.plugin.common-plugin.library-publish")
+    id("org.springframework.boot")
+}
+
+java {
+    withSourcesJar()
+}
+
+tasks {
+    named<Jar>("jar") {
+        archiveClassifier.set("")
+    }
+    withType<BootJar> {
+        enabled = false
+    }
+}